#cs ----------------------------------------------------------------------------

winTrails.au3 v1.0

 AutoIt Version: 3.2.2.0
 Author:         Jon Diercks <jon@diercks.net>

 Script Function:
	monitor active windows, log info to a file

#ce ----------------------------------------------------------------------------

#include <Date.au3>

While 1
	
	; enable special "active" window matching
	AutoItSetOption("WinTitleMatchMode", 4)

	$title = WinGetTitle("active")
	
	; don't log anything if no window is active (e.g. screensaver)
	if ($title<>"") Then
		$pid = WinGetProcess("active")
		$plist = ProcessList()
		for $i = 1 to $plist[0][0]
			if $plist[$i][1]=$pid then
				$pname = $plist[$i][0]
				ExitLoop
			EndIf
		next
		
		$day=_DateDayOfWeek(@WDAY,1)
		$date=_NowCalcDate()
		$time=_DateTimeFormat(_NowCalc(),4)
		$tab=chr(9)
		
		$line =  $day & $tab & $date & $tab & $time & $tab
		$line &= $pname & $tab & $title
		
		if not fileWriteLine("winTrails.txt",$line) Then 
			msgbox(0,"winTrails","logfile write error")
			Exit
		EndIf
	EndIf
	
	Sleep(60000) ;1 minute
	
WEnd